Výkon

ClearAll["Global`*"];

Sériový rezonanční obvod napájený ze zdroje napětí

U1=1;
R=1;
L=0.05;
c=100*(10^(-6));
ω0=(1/(Sqrt[L*c]));
Print["ω0= ",ω0,"  (s^(-1))","   f0= ((ω0)/(2  π))= ",f0=((ω0)/(2π)),"  Hz,  T0= ",T0=(1/f0) ]

uz1=1*Sin[ω0*t];
iz1=1*Sin[ω0*t];
rce={uR[t]==R*iR[t],uL[t]==L*iL'[t],iC[t]==c*uC'[t],uC[0]==0,iL[0]==0,iR[t]==iL[t],iL[t]==iC[t],uR[t]==uz1-u2[t],uL[t]==u2[t]-uC[t]};
dejNezname[rce_]:=Union[Cases[rce,_Symbol[t],{0,∞}]];
nezname=dejNezname[rce];
tmax=10*T0;
res=NDSolve[rce,nezname,{t,0,tmax},StartingStepSize->(10^(-10))][[1]];
Plot[Evaluate[{uz1,uL[t]/.res}],{t,0,tmax},PlotStyle->{{Thickness[0.006],Blue},{Thickness[0.006],Red}},PlotRange->All,AxesLabel->{"t [s]","U1  UL\!\(\*
StyleBox[\(\*
StyleBox[" ",
FontColor->RGBColor[1, 0, 0]]\\ \)]\)[V]"}]

... napětí vyskytující se v obvodech mohou být často větší, než napětí příslušných zdrojů. V tomto případě je uL(t) větší nežli napájecí napětí u1(t).

Paralelní rezonanční obvod napájený zdrojem proudu

rce={iz1==iLR[t]+iC[t],iC[t]==c*u1'[t],u1[t]-uL[t]==R*iLR[t],uL[t]==L*iLR'[t],iLR[0]==0,u1[0]==0};
nezname=dejNezname[rce];
tmax=10*T0;
res=NDSolve[rce,nezname,{t,0,tmax},StartingStepSize->(10^(-10))][[1]];
Plot[Evaluate[{iz1,iLR[t]/.res}],{t,0,tmax},PlotStyle->{{Thickness[0.006],Blue},{Thickness[0.006],Red}},PlotRange->All,AxesLabel->{"t [s]","I1  ILR  [A]"}]

... proudy vyskytující se v obvodech mohou být často větší, než proudy příslušných zdrojů. V tomto případě je iLR(t) větší nežli napájecí proud i1(t).

Stejnosměrný ustálený stav

R=5;
i=1.2;
u=R*i;
Print["P= ",i*u," W"]
Plot[i*u,{t,0,1},PlotStyle->Thick,AxesLabel->{"t[s]","p[W]"}]

Odporový dělič z časově proměnných odporů rezistorů

ClearAll[R1,R2,u1,u2];
u1[t_]:=3.6;
Rmax=(10^6);
Rmin=1;
strmost=(10^2);
R1[t_]:=Rmin+Rmax*0.5*(1+Tanh[-strmost*t]);
R2[t_]:=Rmin+Rmax*0.5*(1+Tanh[strmost*(t+posun)]);
Plot[Evaluate[{R1[t],R2[t]}/.posun->0],{t,-0.1,0.1},AxesLabel->{"t[s]","R1[Ω],R2[Ω]"},PlotStyle->{{Thickness[0.006],Red},{Thickness[0.006],Blue}}]

u2[t_]:=u1[t]*((R2[t])/(R1[t]+R2[t]));
Plot[Evaluate[{u2[t],u1[t]}/.posun->0],{t,-0.1,0.1},AxesLabel->{"t[s]","u1[V],U2[V]"},PlotStyle->{{Thickness[0.006],Red},{Thickness[0.006],Blue}}]
p[t_]:=(((u1[t])^2)/(R1[t]+R2[t]));

Manipulate[Plot[Evaluate[p[t]/.posun->pp],{t,-0.1,0.1},AxesLabel->{"t[s]","p[W]"},PlotStyle->{Thickness[0.006],Red},PlotRange->{Automatic,{0,6*(10^(-5))}}],{pp,((-2)/strmost),(2/strmost)}]