Vázané induktory

Ukázkový obvod

Zadání obvodu - hodnoty součástek a vstupu

ClearAll["Global`*"];

Indukčnost induktoru L2 je stokrát větší nežli indukčnost L1.

Lk=(10^(-1));
L1=Lk*0.1;
L2=Lk*10;

Vzájemná indukčnost obou cívek je velmi dobrá (k = 0.99), tedy mezi cívkami je velmi těsná vazba.

M=0.99*(Sqrt[L1*L2]);
R1=0.1;
R2=1000;

Obvod je napájen zdrojem napětí sinusového průběhu o frekvenci zhruba 50 Hz a amplitudě 10 V.

ω=314;
T=2*(Pi/ω);
uz[t_]:=10*Sin[ω*t];

Popis obvodu

uzel1={((uz[t]-u1[t])/R1)==iL1[t]};
uzel2={((0-u2[t])/R2)==iL2[t]};
induktory={u1[t]==L1*iL1'[t]+M*iL2'[t],u2[t]==L2*iL2'[t]+M*iL1'[t]};
pocs={iL1[0]==0,iL2[0]==0};
dohr=Union[uzel1,uzel2,induktory,pocs];

Řešení

nezn=Cases[dohr,_Symbol[t],{0,∞}]//Union;
tmax=4T;
res=NDSolve[dohr,nezn,{t,0,tmax},StartingStepSize->(10^(-6))T][[1]];

Zobrazení výsledků

Napětí na vstupu (uz) a na výstupu (u2):

Plot[Evaluate[{uz[t],u2[t]/.res}],{t,0,tmax},PlotStyle->{{Thick,Hue[0]},{Thick,Hue[0.63]}},AxesLabel->{"t[s]","uz[V],u2[V]"}]

"... Vidíme, že jsme měli k dispozici zdroj napětí o amplitudě 10 V a získali jsme napětí o amplitudě skoro 100 V! ..."

Proud primárním (iL1) a sekundárním (iL2) vinutím transformátoru:

Plot[Evaluate[{iL1[t],iL2[t]}/.res],{t,0,tmax},PlotStyle->{{Thick,Hue[0]},{Thick,Hue[0.63]}},AxesLabel->{"t[s]","iL1[A],iL2[A]"}]

Celková bilance energie po dobu života vázaných induktorů

"... V notebooku CAO-VazaneInduktory.nb je odvozeno, že platí ..."

ClearAll[L1,L2,M,u1,u2];
u1[t]=L1*iL1'[t]+M*iL2'[t];
u2[t]=L2*iL2'[t]+M*iL1'[t];
u1[t]*iL1[t]+u2[t]*iL2[t]//FullSimplify
%-D[(1/2)L1*((iL1[t])^2)+(1/2)L2*((iL2[t])^2)+M*iL1[t]*iL2[t],t]//Simplify

Ideální transformátor

ClearAll[L1,L2,M,u1,u2];
r1=u1[t]==L1*iL1'[t]+M*iL2'[t];
r2=u2[t]==L2*iL2'[t]+M*iL1'[t];
resder=Solve[{r1,r2},{iL1'[t],iL2'[t]}][[1]]
Simplify[(Sqrt[L1])*iL1'[t]-(Sqrt[L2])*iL2'[t]/.resder]
Limit[%,M->(Sqrt[L1]) (Sqrt[L2])]
Solve[%[[2]]==0,u2[t]][[1]]//Simplify[#,{L1>0,L2>0}]&